groovyで画像に半透明の放射ストライプを描画する

groovyで画像に半透明の放射ストライプを描画するには、以下のコードを実行します。

@Grab(group='org.codehaus.griffon', module='jsilhouette-geom', version='0.4')
import java.awt.*
import java.awt.image.*
import java.io.*
import javax.imageio.*
import org.codehaus.griffon.jsilhouette.geom.*

// 画像に半透明の放射ストライプを描画する
def img = ImageIO.read(new File("sf2.jpg"))
def img2 = new BufferedImage(
  img.getWidth(), img.getHeight(), BufferedImage.TYPE_INT_ARGB
)
gr = img2.createGraphics()
gr.setRenderingHint(
  RenderingHints.KEY_ANTIALIASING,
  RenderingHints.VALUE_ANTIALIAS_ON
)
def radius = img.getWidth()>img.getHeight()?img.getWidth():img.getHeight()
def nrays = 20
def rays = new Rays(img.getWidth()/2, img.getHeight()/2,
  radius, nrays
)
gr.setColor(new Color((int)0x000000))
gr.fill(rays)
gr.dispose()

// 重ね合わせ
gr = img.createGraphics()
gr.setComposite(
  AlphaComposite.getInstance(AlphaComposite.SRC_OVER, 0.4f)
)
gr.drawImage(img2,0,0,null)
gr.dispose()

ImageIO.write(img, "png", new File("compositerays.png"))

元画像

出力画像


動作環境
groovy 1.8.6, JDK7 update4

groovyを使用して画像をレンガ模様で切り取る

groovyを使用して画像をレンガ模様で切り取るには、以下のコードを実行します。

import java.io.*
import java.awt.*
import java.awt.geom.*
import java.awt.image.*
import javax.imageio.*

// 画像をレンガ模様で切り取る 
def img = ImageIO.read(new File("sf2.jpg"))
def img2 = new BufferedImage(
  img.getWidth(), img.getHeight(), BufferedImage.TYPE_INT_ARGB
)

def brickwidth = 20
def brickheight = 10
def padding = 2
def xinterval = brickwidth + padding
def yinterval = brickheight + padding

def gr = img2.createGraphics()
gr.setColor(new Color(1F, 1F, 1F, 1F))

def rc = 0
for(int ly=0;ly<img.getHeight();ly+=yinterval){
  for(int lx=0;lx<img.getWidth()+brickwidth;lx+=xinterval){
    gr.fillRect((int)lx-(rc%2==0?0:brickwidth/2), ly, brickwidth, brickheight)
  }
  rc++;
}

// 切り取り 
gr.setComposite(AlphaComposite.SrcIn)
gr.drawImage(img,0,0,null)
gr.dispose()

ImageIO.write(img2, "png", new File("cutbrick.png"))

元画像

出力画像


動作環境
groovy 1.8.6, JDK7 update4

groovyで画像をスクロールさせる

groovyで画像をスクロールさせるには、以下のコードを実行します。

@Grab(group='com.jhlabs', module='filters', version='2.0.235')
import java.awt.*
import java.awt.image.*
import java.io.*
import javax.imageio.*
import com.jhlabs.composite.*
import com.jhlabs.image.*

// 画像をスクロールさせる
def img = ImageIO.read(new File("sf2.jpg"))
def imga = new BufferedImage(
  img.getWidth(), img.getHeight(), 
  BufferedImage.TYPE_INT_ARGB
)
def of = new OffsetFilter(20, 10, true)
of.filter(img, imga)

ImageIO.write(imga, "png", new File("offset.png"))

元画像

出力画像


動作環境
groovy 1.8.6, JDK7 update4

groovyで画像を夢のように切り取る

groovyで画像を夢のように切り取るには、以下のコードを実行します。

@Grab(group='com.jhlabs', module='filters', version='2.0.235')
import java.awt.*
import java.awt.geom.*
import java.awt.image.*
import java.io.*
import javax.imageio.*
import com.jhlabs.composite.*
import com.jhlabs.image.*

// 画像を夢のように切り取る
def img = ImageIO.read(new File("sf2.jpg"))
// マスクを作成 
def img2 = new BufferedImage(
  img.getWidth(), img.getHeight(), BufferedImage.TYPE_INT_ARGB
)
def gr = img2.createGraphics()
gr.setRenderingHint(
  RenderingHints.KEY_ANTIALIASING,
  RenderingHints.VALUE_ANTIALIAS_ON
)
gr.setColor(new Color(1F, 1F, 1F, 1F))
def rr = new RoundRectangle2D.Double(
    0.0, 0.0, img.getWidth()-1, img.getHeight()-1, 20.0*2, 20.0*2)
gr.fill(rr)
gr.dispose()

// 揺らす
def wavelen = 10f
def rf = new RippleFilter()
rf.setXAmplitude((float)wavelen/2)
rf.setXWavelength(wavelen)
rf.setYAmplitude((float)wavelen/2)
rf.setYWavelength(wavelen)
img2 = rf.filter(img2, null)

def img3 = new BufferedImage(
  (int)img2.getWidth()+wavelen, (int)img2.getHeight()+wavelen, BufferedImage.TYPE_INT_ARGB
)
gr = img3.createGraphics()
gr.drawImage(img2,(int)wavelen/2,(int)wavelen/2,null)
gr.dispose()

// リサイズ
img2 = new BufferedImage(
  img.getWidth(), img.getHeight(), BufferedImage.TYPE_INT_ARGB
)
ScaleFilter sf = new ScaleFilter(img.getWidth(), img.getHeight())
img3 = sf.filter(img3, img2)

// ぼかす
def gf = new GaussianFilter()
gf.setRadius(10f)
img3 = gf.filter(img3, null)

// 切り取り 
gr = img3.createGraphics()
gr.setComposite(AlphaComposite.SrcIn)
gr.drawImage(img,0,0,null)
gr.dispose()

ImageIO.write(img3, "png", new File("dreamy.png"))

元画像

出力画像


動作環境
groovy 1.8.6, JDK7 update4

groovyで盛り上がった枠を描画する

groovyで盛り上がった枠を描画するには、以下のコードを実行します。

import java.awt.*
import java.awt.image.*
import java.awt.geom.*
import java.io.*
import javax.imageio.*

// 盛り上がった枠を描画する
def img = ImageIO.read(new File("sf2.jpg"))

def bwidth = 10

def img2 = new BufferedImage(
  img.getWidth()+bwidth*2, img.getHeight()+bwidth*2, 
  BufferedImage.TYPE_INT_ARGB
)
def gr = img2.createGraphics()
def base = new Color(0x808080)
def hsb = new float[3]
Color.RGBtoHSB(base.getRed(), base.getGreen(), base.getBlue(), hsb)
def brighter = new Color(Color.HSBtoRGB(hsb[0], hsb[1], (float)hsb[2]*1.2))
def brighter2 = new Color(Color.HSBtoRGB(hsb[0], hsb[1], (float)hsb[2]*1.4))
def darker = new Color(Color.HSBtoRGB(hsb[0], hsb[1], (float)hsb[2]*0.8))
def darker2 = new Color(Color.HSBtoRGB(hsb[0], hsb[1], (float)hsb[2]*0.6))

for(lw=0;lw<bwidth;lw++){
  gr.setColor(brighter2)
  gr.drawLine(lw, lw, img2.getWidth()-lw-1, lw)
  gr.setColor(brighter)
  gr.drawLine(lw, lw, lw,img2.getHeight()-lw-1)
  gr.setColor(darker)
  gr.drawLine(img2.getWidth()-lw-1, lw, img2.getWidth()-lw-1, img2.getHeight()-lw-1)
  gr.setColor(darker2)
  gr.drawLine(lw, img2.getHeight()-lw-1, img2.getWidth()-lw-1, img2.getHeight()-lw-1)
}
gr.drawImage(img, bwidth, bwidth, null)
gr.dispose()

ImageIO.write(img2, "png", new File("raisedborder.png"))

元画像

出力画像


動作環境
groovy 1.8.6, JDK7 update4