groovyで画像をタイル模様で切り取って影をつける

groovyで画像をタイル模様で切り取って影をつけるには、以下のコードを実行します。

@Grab(group='com.jhlabs', module='filters', version='2.0.235')
import java.io.*
import java.awt.*
import java.awt.geom.*
import java.awt.image.*
import javax.imageio.*
import com.jhlabs.composite.*
import com.jhlabs.image.*

// 画像をタイル模様で切り取って影をつける
def img = ImageIO.read(new File("sf2.jpg"))
def img2 = new BufferedImage(
  img.getWidth(), img.getHeight(), BufferedImage.TYPE_INT_ARGB
)
def gr = img2.createGraphics()
// レンダリングヒントを設定
def rh = new
  RenderingHints(RenderingHints.KEY_ANTIALIASING,
  RenderingHints.VALUE_ANTIALIAS_ON)

rh.put(RenderingHints.KEY_RENDERING,
  RenderingHints.VALUE_RENDER_QUALITY)

gr.setRenderingHints(rh)

def boxsize = 18
def rsize = 2
def padding = 4
def interval = boxsize + padding

gr.setColor(new Color(1F, 1F, 1F, 1F))

for(int ly=0;ly<img.getHeight();ly+=interval){
  for(int lx=0;lx<img.getWidth();lx+=interval){
    def rr = new RoundRectangle2D.Double(
      lx, ly, boxsize, boxsize, rsize*2, rsize*2)
    gr.fill(rr)
  }
}

// 切り取り 
gr.setComposite(AlphaComposite.SrcIn)
gr.drawImage(img,0,0,null)
gr.dispose()

def sf = new ShadowFilter()
// 半径
sf.setRadius(7f)
// 透明度
sf.setOpacity(0.9f)
// 角度
sf.setAngle((float)300f/180f*ImageMath.PI)
// 距離
sf.setDistance(5f)
// 影の色
sf.setShadowColor((int)0xff202020)
// 影のマージン
sf.setAddMargins(false)
// 影のみにするか
sf.setShadowOnly(false)
img2 = sf.filter(img2, null)

ImageIO.write(img2, "png", new File("tileshadow.png"))

元画像

出力画像


動作環境
groovy 1.8.6, JDK7 update4